Program 9.1

/\* This section of code computes the treatment selection and censoring weights. This is accomplished in 4 steps:

1) multinomial model to compute numerator of treatment selection weights;

2) multinomial model to compute denominator of treatment selection weights;

3) binomial model to compute numerator of censoring adjustment weights;

4) binomial model to compute denominator of censoring adjustment weights. \*/

/\* treatment selection weights: numerator calculation

(probability of treatment using only baseline covariates) \*/

**PROC** **LOGISTIC** DATA = INPDS;

CLASS VIS THERAPY PR1TRTA PR1TRTB PR1TRTC GENDER ORIGIN2 BHOSP BEVNT;

MODEL TRT = VIS THERAPY PR1TRTA PR1TRTB PR1TRTC GENDER ORIGIN2 BHOSP

BEVNT AGEYRS BGAF BBPRS

/LINK=GLOGIT;

OUTPUT OUT=PREDTRT0(WHERE=(TRT=\_LEVEL\_)) PRED=PREDTRT0;

**run**;

/\* treatment selection weights: denominator calculation (probability of treatment with baseline covariates and time-dependent covariates) \*/

**PROC** **LOGISTIC** DATA = INPDS;

CLASS VIS THERAPY PR1TRTA PR1TRTB PR1TRTC GENDER ORIGIN2 BHOSP BEVNT

PR1EVNT PR1HOSP;

MODEL TRT = VIS THERAPY PR1TRTA PR1TRTB PR1TRTC GENDER ORIGIN2 BHOSP

BEVNT AGEYRS BGAF BBPRS PR1EVNT PR1HOSP PR1BPRS PR1GAFC

/LINK=GLOGIT;

OUTPUT OUT=PREDTRT1(WHERE=(TRT=\_LEVEL\_)) PRED=PREDTRT1;

**run**;

/\* censoring adjustment weights: numerator calculation

(probability of censoring using only baseline covariates) \*/

ODS LISTING EXCLUDE OBSTATS;

**PROC** **GENMOD** DATA = INPDS;

CLASS PATSC VIS THERAPY TRTA TRTB TRTC GENDER ORIGIN2 BHOSP BEVNT;

MODEL CFLAG = VIS THERAPY TRTA TRTB TRTC GENDER ORIGIN2 BHOSP BEVNT

AGEYRS BGAF BBPRS

/DIST = BIN LINK = LOGIT TYPE3 OBSTATS;

REPEATED SUBJECT = PATSC / TYPE = EXCH;

ODS OUTPUT OBSTATS = PREDCEN0(RENAME=(PRED=PREDCEN0));

**RUN**;

ODS LISTING SELECT ALL;

/\* censoring adjustment weights: denominator calculation (probability of censoring using baseline covariates and time-dependent covariates) \*/

ODS LISTING EXCLUDE OBSTATS;

**PROC** **GENMOD** DATA = INPDS;

CLASS PATSC VIS THERAPY TRTA TRTB TRTC GENDER ORIGIN2 BHOSP BEVNT

EVNT HOSP;

MODEL CFLAG = VIS THERAPY TRTA TRTB TRTC GENDER ORIGIN2 BHOSP BEVNT

EVNT HOSP AGEYRS BGAF BBPRS BPRS GAFC

/DIST = BIN LINK = LOGIT TYPE3 OBSTATS;

REPEATED SUBJECT = PATSC / TYPE = EXCH;

ODS OUTPUT OBSTATS = PREDCEN1(RENAME=(PRED=PREDCEN1));

**RUN**;

ODS LISTING SELECT ALL;